Option Explicit
Sub H_Sample001()
    'ոH_Data01
    Dim myCht    As Chart
    Dim myChtobj As ChartObject
    Dim mySht1   As Worksheet
    Dim mySht2   As Worksheet
    Dim myRng1   As Range
    Dim myRng2   As Range
    Dim myRng3   As Range
    Dim i        As Long
    'w¦
    Set mySht1 = Worksheets("H_Data01")
    Set mySht2 = Worksheets.Add
    Set myRng1 = mySht1.Range("D1:G1")          'ƽd
    Set myRng2 = mySht1.Range("D2:G2")
    Set myRng3 = mySht1.Range("C2")
    For Each myChtobj In mySht2.ChartObjects
        myChtobj.Delete
    Next
    For i = 1 To 10
        Set myCht = Charts.Add
        With myCht
            .ChartType = xlRadarFilled
            .SetSourceData Source:=mySht1.Range("A1"), PlotBy:=xlRows
            With .SeriesCollection(1)
                .XValues = myRng1
                .Values = myRng2.Offset(i - 1)
                .Name = myRng3.Offset(i - 1)
            End With
            .Location Where:=xlLocationAsObject, Name:=mySht2.Name
        End With
        With mySht2.ChartObjects
            Set myCht = .Item(.Count).Chart
        End With
        With mySht2.Shapes(mySht2.Shapes.Count)
            .Width = 150
            .Height = 150
        End With
        With myCht
            With .PlotArea
                .Left = 20
                .Top = 20
                .Width = 100
                .Height = 100
                With .Interior
                    .ColorIndex = 2
                    .PatternColorIndex = 1
                    .Pattern = xlSolid
                End With
            End With
            With .ChartTitle
                .Left = 10
                .Top = 5
                .Font.Size = 10
            End With
            With .Axes(xlValue)
                .MinimumScale = 0
                .MaximumScale = 100
                .MinorUnitIsAuto = True
                .MajorUnitIsAuto = True
            End With
            .HasLegend = False
        End With
    Next
    mySht2.Range("A1").Activate
    Set myRng1 = Nothing            '
    Set myRng2 = Nothing
    Set myRng3 = Nothing
    Set mySht1 = Nothing
    Set mySht2 = Nothing
    Set myCht = Nothing
    Set myChtobj = Nothing
End Sub

